Why are my debug messages printing twice? (print command) - SOLVED

SnapCracklins

I am getting in the habit of building debug messages into my work but for some reason all my debug messages are printing twice. Anyone else have this problem and is it even worth worrying about? Made a simple event generator, it works great for what i need but it is printing the debug messages 2-4 times instead of just once. Figured it is best to figure this out now before it becomes a huge problem.

The node in question is a simple Area2D just waiting for a player to enter, which flips a boolean that allows a button press to trigger/progress the event.

extends Area2D


class_name event

var triggerState = false
enum eventProgress {NOT, ON, DONE}
var eventState = eventProgress.NOT


func _ready():
	self.connect("body_entered", self, "trigger_ready")
	self.connect("body_exited", self, "trigger_disable")


func _input(event):
	if Input.is_action_pressed("ui_accept"): 
		trigger_event()


func trigger_ready(body):
	if body.name == "Player":
		triggerState = true
		print("Can trigger.")


func trigger_disable(body):
	if body.name == "Player":
		triggerState = false
		print("Can no longer trigger.")


func trigger_event():
	if triggerState == true:
		match eventState:
			eventProgress.NOT:
				print("This could be a hiding place...")
				eventState = eventProgress.ON
			eventProgress.ON:
				print("You trigger an event.")
				eventState = eventProgress.DONE
			eventProgress.DONE:
				print("This event is complete.")

DaveTheCoder

Just a guess, but you may want to use Input.is_action_just_pressed() instead of Input.is_action_pressed().

SnapCracklins

@DaveTheCoder said: Just a guess, but you may want to use Input.is_action_just_pressed() instead of Input.is_action_pressed().

Tried that, but no luck. Also my debug messages for entering/exiting the trigger area also post four times any time i enter/exit the trigger area.

cybereality

I see two problems. The classname should not be "event" I believe that may be a restricted keyword. You can use something more descriptive like AreaEvent. Second, you are modifying the match statement while it is running. This is what is probably causing the issue. What you want to have is an additional variable, like nextEventState, set that in the match statement, and then at the end (outside the match) set eventState equal to nextEventState.

duane

@SnapCracklins

I made a simple project and pasted the code clip in, but I'm only getting one debug message when I enter/leave the area. I don't think the problem is in the code you pasted. Are you sure you don't have extra area2d nodes involved (besides one for the player and one for the target)?

SnapCracklins

I think I figured it out. I believe @cybereality was right. I used a second variable to hold event state and when I did, it solved the issue. I also rearranged nodes and such and I must have had a hiccup there. Honestly, I rebuilt it ground up and now it works great. I also cleaned up the state machine to make the code a bit more readable. I am loving state machines, in case it is not obvious. =)

A note to humbly remember variables are references, so you always gotta check them.

My solution:

extends Area2D

class_name eventPrototype
# class tree is area 2d parent
# children are CollisionShape2D, ColorRect, AnimationPlayer w AnimatedSprite child

enum eventStatus {BEFORE, DURING, AFTER}

var currentEvents = eventStatus.BEFORE
var nextCurrentEvent = eventStatus.DURING
var can_run_event = false

# animation player w animated sprite child
onready var _prompt = $PromptPlayer
onready var _promptBox = $PromptPlayer/Prompt


### on ready, hide sprite and connect enter/exit signals __________________
func _ready():
	_promptBox.hide()
	self.connect("body_entered", self, "on_body_entered")
	self.connect("body_exited", self, "on_body_exited")
	pause_mode = self.PAUSE_MODE_PROCESS

### check if player is present to validate event can play _________________
func on_body_entered(body):
	if body.name == "Lydia":
		can_run_event = true
		print("Event box enter.")
		prompt_on()

func on_body_exited(body):
	if body.name == "Lydia":
		can_run_event = false
		print("Event box exit.")
		prompt_off()


### handle input to access event and check state machine __________________
func _input(event):
	if Input.is_action_just_pressed("ui_accept"):
		print("Can run = " + str(can_run_event))
		if can_run_event == true:
			currentEventstatus()


### core event state machine ______________________________________________

func currentEventstatus():
	match currentEvents:
		eventStatus.BEFORE:
			before_state()
		eventStatus.DURING:
			during_state()
		eventStatus.AFTER:
			after_state()

### reveal visual prompt and vice versa ___________________
func prompt_on():
	_prompt.play("visible")
	_promptBox.show()

func prompt_off():
	_promptBox.hide()


### actions for states _____________________________________
func before_state():
	print("Event ready...")
	### allows for "double clicking" event to prevent accidental trigger
	event_next()


func during_state():
	nextCurrentEvent = eventStatus.AFTER
	get_tree().paused = true
	print("An event triggered.")
	### put an event here
	event_next()
	

func after_state():
	currentEvents = nextCurrentEvent
	get_tree().paused = false
	print("Event already done.")
	can_run_event = false


func event_next():
	currentEvents = nextCurrentEvent