Projectile spawns in the wrong place

Meruva

I am trying to create a projectile launcher, but when I launch my projectiles it launches 'from' the player, instead of the position it was already in.

The mechanic is this, I click an hold on the player object, drag the projectile and when I release the mouse button it should launch in the direction of the 'aim_line'

here is a video of the issue.

and here is my code:

extends KinematicBody2D

var mouse_over: bool = false
var is_selected : bool = false
var aim_dir: Vector2 = Vector2.ZERO

onready var aim_line: Line2D = $AimLine
onready var center_point: Position2D = $CenterPoint
var bomb_inst : RigidBody2D = null
export (PackedScene) var Bomb

func _ready():
	print_var_change_event("aim Point [0]", aim_line.points[0])
	print_var_change_event("player position",position)
	


func _on_Player_mouse_entered():
	mouse_over = true
	print("Mouse Over is true:" + str(mouse_over))
	


func _on_Player_mouse_exited():
	mouse_over = false
	print("Mouse Over is true:" + str(mouse_over))



func _physics_process(delta):
		
	if (mouse_over): #I specifically want to check if the MOUSE_OVER variable is true before checking to see if the mouse button has been clicked, so I have done a layered if instead of AND
		if Input.is_action_just_pressed("mouse_select"):
			aim_line.add_point(get_global_mouse_position())
			is_selected = true
			bomb_inst = create_bomb_instance()
			
			
	if (is_selected):
		if (aim_line.points[1]):
			aim_line.points[1] = get_local_mouse_position()
	#				print_var_change_event("aim point [1]", aim_line.points[1])
			bomb_inst.global_position = get_global_mouse_position()
#			print(bomb_inst.global_position)
		

	if (!mouse_over && Input.is_action_just_released("mouse_select")):
		if (aim_line.get_point_count() > 1):
			bomb_inst.global_position = get_global_mouse_position()
			aim_dir = get_aim_direction()
			
			print_var_change_event("angle of aim",aim_dir.normalized())
			print(get_global_mouse_position())
			
			launch_projectile(bomb_inst, aim_dir)
			aim_line.remove_point(1)
		is_selected = false


func print_var_change_event(varName, var_value):
	print(str(varName) + " changed to: " + str(var_value))
	
func create_bomb_instance():
	var bomb_instance : RigidBody2D = Bomb.instance()
	add_child(bomb_instance)
	return bomb_instance 
	
func launch_projectile(projectile: RigidBody2D, direction: Vector2):
	projectile.apply_central_impulse(direction.normalized() * 2000)
	
func get_aim_direction():
	return aim_line.points[0] - aim_line.points[1]

Megalomaniak

What befuddles me is your mouse cursor being upside down...

Have you tried subtracting that direction.normalized() on line 69? If not that I'd look at 72.

xyz

What happens if you change 2000 to 1 and launch from a position above the ground?

Meruva

@xyz said: What happens if you change 2000 to 1 and launch from a position above the ground?

same thing. the projectile spawns from the character instead of launching from its original spot

Meruva

@Megalomaniak said: What befuddles me is your mouse cursor being upside down...

Have you tried subtracting that direction.normalized() on line 69? If not that I'd look at 72.

how do you mean my mouse cursor is upside down? what would you suggest the issue is with line 72? or 69?

Megalomaniak

@Meruva said: how do you mean my mouse cursor is upside down?

maybe you just recorded the video of the display with your phone upside down but it looks like the mouse is pointing downwards, which is unusual.

@Meruva said: what would you suggest the issue is with line 72? or 69?

I mean try it out with a minus sign added in front of the direction variable on line 69

xyz

There may be something else in the scene causing it. Post a minimal project that reproduces the problem and we'll take a look. Btw what happens if you remove the ground?

Meruva

@Megalomaniak said: What befuddles me is your mouse cursor being upside down...

Have you tried subtracting that direction.normalized() on line 69? If not that I'd look at 72.

so my issue isn't the direction that the projectile travels. its where the projectile launches from. It should launch from where it currently is (under the mouse) but it is launching from the player object. In the video I am dragging the projectiles around by holding the left mouse button down, and when I release it the projectile should launch from where it is. Instead of the players location, where it starts. Does that make sense?

Megalomaniak

So you should create and add to the scene a launcher object, initially from the player and once it's created from the player it should not be recreated again if a instance already exists. That instance then should have it's own logic for launching itself again.

Currently in your code I see no check for if such a instance already exists so it's just creating a new one each time I guess.

Meruva

@Megalomaniak said: So you should create and add to the scene a launcher object, initially from the player and once it's created from the player it should not be recreated again if a instance already exists. That instance then should have it's own logic for launching itself again.

Currently in your code I see no check for if such a instance already exists so it's just creating a new one each time I guess.

This was actually a great suggestion and flaw with my code. Thank you, although I have fixed it, the issue still occurs. I have even made every Projectile display its instance ID above itself to ensure they are all different, and they are...but still the same thing. They don't launch from the point that I drug the Projectile to, the launch from the Player

Megalomaniak

I would give the bomb/projectile it's own script and put all that movement code in there so they would be launching themselves. Might also help with debugging it since it will be self contained.

cybereality

It's this function:

func create_bomb_instance():
    var bomb_instance : RigidBody2D = Bomb.instance()
    add_child(bomb_instance)
    return bomb_instance

You are adding the bomb as a child on the player, so it's position is relative to the player.

It should be this:

get_parent().add_child(bomb_instance)

Meruva

@Megalomaniak said: I would give the bomb/projectile it's own script and put all that movement code in there so they would be launching themselves. Might also help with debugging it since it will be self contained.

This I have already done, but unfortunately it didn't change the issue

Meruva

@cybereality said: It's this function:
func create_bomb_instance():
    var bomb_instance : RigidBody2D = Bomb.instance()
    add_child(bomb_instance)
    return bomb_instance 
You are adding the bomb as a child on the player, so it's position is relative to the player.

It should be this:
get_parent().add_child(bomb_instance)

I tried this also. No change, the bomb actually follows the cursor whilst being held...which is correct, so the positioning works to a degree, even though it is a child of the player. Its only when I launch it that things dont work

cybereality

Then it is this line:

bomb_inst.global_position = get_global_mouse_position()

The bomb is already at the correct position, so you can remove that line altogether. This is also why you should never use global positioning as it just confuses things.

xyz

Posting the minimal reproduction project would really save everyone's time. Posted code looks like it should work, so it may be something else. It's a guessing game without seeing the complete thing.

Meruva

@cybereality said: Then it is this line:
bomb_inst.global_position = get_global_mouse_position()
The bomb is already at the correct position, so you can remove that line altogether. This is also why you should never use global positioning as it just confuses things.

Thank you for the advice, how would you suggest that I tackle instead of using global positiong? Should I use locl instead?

Meruva

@xyz said: Posting the minimal reproduction project would really save everyone's time. Posted code looks like it should work, so it may be something else. It's a guessing game without seeing the complete thing.

Apologies, I am not sure what you mean by this. To me, the code I have posted is the minimum to produce the issue, as I only wrote code to do this. Maybe I am misunderstanding something?

I don't mean to be difficult or time-waste I'm just new lol Thanks for helping

xyz

I meant to post (attach) actual Godot project files, stripped of everything except nodes/code that can still reproduce the problem. In software development, this is often referred to as minimal reproduction test case.

Meruva

I have re-written the code for clarity and re-recorded the video, its short but gives more detail: Video explaining the issue

extends KinematicBody2D
var mouse_over: bool = false
var is_selected : bool = false setget set_selected
var aim_dir: Vector2 = Vector2.ZERO

onready var aim_line: Line2D = $AimLine
onready var center_point: Position2D = $CenterPoint
var bomb_inst : RigidBody2D = null
export (PackedScene) var Bomb


func _physics_process(delta):
	
	if (Input.is_action_just_pressed("mouse_select") and mouse_over):
		set_selected(true)
		create_bomb()
		add_point_one()
	
	
	if Input.is_action_just_released("mouse_select"):
		set_selected(false)
		bomb_inst.launch_projectile(get_aim_dir(),2000)
		remove_point_one()
		
	if is_selected:
		point_one_follow_mouse()
		projectile_follow_point_one()



func _on_Player_mouse_entered():
	mouse_over = true
	print("Mouse Over is true:" + str(mouse_over))


func _on_Player_mouse_exited():
	mouse_over = false
	print("Mouse Over is true:" + str(mouse_over))
	
	
func set_selected(status: bool):
	if is_selected != status:
		is_selected = status
	print(is_selected)


func add_point_one():
	if aim_line.get_point_count() < 2:
		aim_line.add_point(get_local_mouse_position())
		
		
func remove_point_one():
	if aim_line.get_point_count() > 1:
		for x in range(aim_line.points.size(), 0,-1) :
			print(aim_line.points.size())
			aim_line.remove_point(x)


func point_one_follow_mouse():
	if aim_line.points[1]:
		aim_line.points[1] = get_local_mouse_position()


func projectile_follow_point_one():
	if aim_line.get_point_count() == 2 and bomb_inst != null:
		bomb_inst.position = aim_line.points[1]


func get_aim_dir():
	if aim_line.get_point_count() > 1:
		return aim_line.points[1].direction_to(aim_line.points[0])


func create_bomb():
	if bomb_inst == null:
		bomb_inst = Bomb.instance()
		add_child(bomb_inst)

The projectile has this code: extends RigidBody2D

onready var textLabel = $Label
var pos = position

func launch_projectile(direction: Vector2, impulse_strength: int):
	apply_central_impulse(direction.normalized() * impulse_strength)


func _ready():
	textLabel.text = str(get_instance_id()) + "-" + str(pos)

func _physics_process(delta):
	pos = position
	textLabel.text = str(get_instance_id()) + "-" + str(pos)