Is there a simpler way to code movement that involves both a walk and a run?

PhantomFox128

I've been using some code that allows the player to walk and run by basically changing their movement speed if a second button is held down while moving (I've stripped out some extra code to show the bare bones of it):

func _physics_process(delta):
	
#MOVEMENT
	if Input.is_action_pressed("right"):
		if Input.is_action_pressed("run"):
			velocity.x = runSpeed;
		else:
			velocity.x = walkSpeed;
	elif Input.is_action_pressed("left"):
		if Input.is_action_pressed("run"):
			velocity.x = -runSpeed;
		else:
			velocity.x = -walkSpeed;
	else:
		if is_on_floor():
			velocity.x = 0;

This largely works, but I'm wondering if there's a more easier/cleaner way of going about it. I'm asking because I've yet to see a tutorial that actually uses more than one movement speed. The vast majority of tutorials I see use only one fixed movement speed and never go beyond that, usually using something along the lines of

Input.get_action_strength("right") - Input.get_action_strength("left")

which I guess works okay, but that's not enough for what I need and I've never figured out how to get both a walk and a run function from it without something going wrong, hence why I use all the code above.

cybereality

Yes, you use a speed multiplier.

    func _physics_process(delta):
        var speed_multiplier = 1.0
        if Input.is_action_pressed("run"):
            speed_multiplier = 1.5
        if Input.is_action_pressed("right"):
            velocity.x = walkSpeed * speed_multiplier;
        elif Input.is_action_pressed("left"):
            velocity.x = -walkSpeed * speed_multiplier;
        else:
            if is_on_floor():
                velocity.x = 0;

PhantomFox128

@cybereality said: Yes, you use a speed multiplier.

Thanks for this! Works perfectly!

One thing I've noticed (that was also present in the original code) is that moving right always seems to have priority over moving left. If the player is moving left and then presses right while also holding left, they'll turn around and go right, which is fine, that's actually what I want, but the same thing doesn't happen they press left while moving right. They continue to go right unless the button is released.

Megalomaniak

@Azerkit said:

One thing I've noticed (that was also present in the original code) is that moving right always seems to have priority over moving left.

The if statement takes precedence/priority over the elif.

cybereality

This would fix the overriding buttons (so both can be pressed)

        velocity.x = 0.0
        if Input.is_action_pressed("right"):
            velocity.x += walkSpeed * speed_multiplier;
        if Input.is_action_pressed("left"):
            velocity.x -= walkSpeed * speed_multiplier;

PhantomFox128

@cybereality said: This would fix the overriding buttons (so both can be pressed)

Took me awhile to figure what I was doing wrong with this one. I still had left set to -walkSpeed instead of using the "-=." Still getting a an odd issue where if both are pressed, the player will always face to the left now and the walk/run animations keep playing instead of going to idle, but other than that, it works!

I'm also curious: instead of having the two cancel each other, how would you go about setting it so that if one direction is pressed while the other one is held down, the new one takes over?

xyz

@Azerkit said: I'm also curious: instead of having the two cancel each other, how would you go about setting it so that if one direction is pressed while the other one is held down, the new one takes over?

In that case, querying the current state won't be enough. You'll need to catch the press/release events as well. For most "natural" feel I typically use the following logic: If direction is just pressed - it becomes active even if other direction is held down If direction is just released - check if other direction is already held down and make it active, otherwise make none active.

var direction =  0
func _physics_process(delta):
	if Input.is_action_just_pressed("left"):
		direction = -1
	elif Input.is_action_just_pressed("right"):
		direction = 1
	elif Input.is_action_just_released("left"):
		direction = 0
		if Input.is_action_pressed("right"):
			direction = 1
	elif Input.is_action_just_released("right"):
		direction = 0
		if Input.is_action_pressed("left"):
			direction = -1

	velocity.x = direction * speed * speed_multiplier