Marble game in 2d

Far

I'm starting my journey with Game dev (not with programming - as I'm an old apps programmer) and I'm trying to figure out how to start implementing my idea.

Let me start with explaining it. I would like to create a simple 2d game, where the player can rotate the scene to right or left and the ball will fall in that direction. In other words, I would like to do a marble game but only in 2d.

I've started this by adding RigidBody2D as a ball and now I'm trying to rotate the TileMap when the user presses the left or right key. Is this a good direction? Or should I try to implement this in a different way?

Also I'm struggling a bit with the code that will rotate the TileMap using the center point of it.

Thanks for the help!

cybereality

So rotating a tilemap is possible. But it doesn't look like you can rotate around an arbitrary point, and it messes up the physics anyhow (since the tiles are static bodies). However, you can rotate the Camera2D and it will appear as if the world is rotating. Set the rotating to on on the camera, and then in your player script, adjust the rotation on the camera based on input. The tricky part is that you have to also adjust the gravity (and all player controls) to account for the new rotation. I did some tests and it should work, but I couldn't get the math exactly right. But I think that is one way to do it.

Far

Clear - your solution sounds very reasonable. I've also thought about using the Camera2D for that - but then I couldn't figure out what to do with the gravity (for example: how to force the ball to move). But if you say that this should work then I will check it out.

Thanks a lot for this idea, I appreciate your help!

cybereality

Yeah, I got gravity mostly working with this line.

var gravity = Vector2(0, 10)
velocity += gravity.rotated(camera_rotation) * delta

I still couldn't get the left/right controls working, but I'm sure there is a way to do it.

Far

oh, nice - I will use that as my starting point! Thanks again!

cybereality

Note, I put gravity as 10 just for the example, but since I'm using delta you'd want a value like 1000, or something like that, to actually work correctly.

Far

@cybereality said: Note, I put gravity as 10 just for the example, but since I'm using delta you'd want a value like 1000, or something like that, to actually work correctly.

OK, I will do some experiments ;) - which is quite fun - doing stuff different then a CRUD apps :+1:

cybereality

Here is my player code for the rotating tilemap. Seems to work good (the full project is too big to upload).

extends KinematicBody2D

export var gravity = Vector2()
export var move_speed = 0
export var rot_speed = 0
export var jump_speed = 0
export var max_speed = 0
export var friction = 0.0
var velocity = Vector2()
var move_dir = Vector2()
var camera_rotation = 0
var jumping = false
	
func _physics_process(delta):
	var move_vec = move_dir * move_speed * delta
	move_vec.x = clamp(move_vec.x, -max_speed, max_speed)
	move_vec.y = clamp(move_vec.y, -max_speed, max_speed)
	velocity += move_vec
	velocity -= velocity * friction * delta
	velocity += gravity.rotated(camera_rotation) * delta
	velocity = move_and_slide(velocity, Vector2.UP.rotated(camera_rotation))
	if jumping and is_on_floor():
		jumping = false

func _process(delta):
	move_dir = Vector2.ZERO
	if Input.is_action_pressed("move_left"):
		move_dir += Vector2.LEFT.rotated(camera_rotation)
	if Input.is_action_pressed("move_right"):
		move_dir += Vector2.RIGHT.rotated(camera_rotation)
	if Input.is_action_pressed("jump") and not jumping and is_on_floor():
		var jump_dir = Vector2.UP.rotated(camera_rotation)
		velocity += jump_speed * jump_dir
		jumping = true
	if Input.is_action_pressed("rotate_left"):
		camera_rotation += rot_speed * delta
	if Input.is_action_pressed("rotate_right"):
		camera_rotation -= rot_speed * delta