Set pixel value in texture3D?

itgiawa

I'm trying to set the value of a pixel in a texture3D object, but it doesnt appear to be working:

var width = 64
	var height = 64
	var depth = 64
	var texture3D = Texture3D.new()
	texture3D.create(64, 64, 64, Image.FORMAT_RGB8)
	var image = Image.new()
	image.create(width, height, false, Image.FORMAT_RGB8)

	texture3D.set_layer_data(image, 0)
	texture3D.data['layers'][0].lock()
	texture3D.data['layers'][0].set_pixel(0, 0, Color(0.7, 0.3, 0.8))
	var value = texture3D.data['layers'][0].get_pixel(0, 0)
	print("set pixel value:", value)

output:

set pixel value:0,0,0,1

Maybe the problem has something to do with locking? Do I need to unlock? I'm not sure what locking does, since I assume this is a single thread...

cybereality

Yes, you have to lock and unlock. It's for reading and writing data, not multi-threading. I think it will be easier if you lock the image, do the set pixels, unlock it, and then set the texture3D layer.

itgiawa

@cybereality Thanks, I'll try that, but something seems to be wrong with my image:

       var image = Image.new()
	image.create(width, height, false, Image.FORMAT_RGB8)
	image.lock()
	image.set_pixel(0, 0, Color(0.7, 0.3, 0.8))
	image.unlock()
	var value = image.get_pixel(0, 0)
	print("set pixel value:", value)

This returns a value of 0, 0, 0, 1

Maybe my image format is wrong? or print is being weird?

cybereality

The image also has to be locked to read pixel values. So if you move the "image.unlock()" line below the "get_pixel()" line it will work.

itgiawa

@cybereality ok that works for the image. Thank you! but I still cant seem to read from the texture, even using your technique?

    image.create(width, height, false, Image.FORMAT_RGB8)

image.lock()
image.set_pixel(0, 0, Color("#ffffffff"))
print(image.get_pixel(0, 0))
image.unlock()

texture3D.set_layer_data(image, 0)

texture3D.data['layers'][0].lock()
print(texture3D.data['layers'][0].get_pixel(0, 0))
texture3D.data['layers'][0].unlock()

this outputs:

1,1,1,1 0,0,0,1

cybereality

It works like this:

extends Node2D

func _ready():
	create_image(64, 64)
	
func create_image(width, height):
	var image = Image.new()
	image.create(width, height, false, Image.FORMAT_RGB8)
	image.lock()
	image.set_pixel(0, 0, Color(0.7, 0.3, 0.8))
	var value = image.get_pixel(0, 0)
	image.unlock()
	print("set pixel value: ", value)
	
	var tex = Texture3D.new()
	tex.create(width, height, 4, Image.FORMAT_RGB8, 0)
	tex.set_layer_data(image, 0)
	var tex_image = tex.get_layer_data(0)
	tex_image.lock()
	value = tex_image.get_pixel(0, 0)
	tex_image.unlock()
	print("get pixel value: ", value)

itgiawa

@cybereality thanks! that works, but on line 12 and 21 did you mean to use unlock()? I'm not sure why you would lock it each time you access it and never unlock it?

cybereality

Sorry, yeah that was a typo.