How to bounce bullet in the Scene

adcoding

I'm creating a funny game where the player can shoot sheep. I added the bullet spawn when the user click the mouse... Everything works perfectly.

But I want that the bullets can bounce in the scene.

How can I add this function?

# Player.gd - called when we press the shoot button - sapwn a new bullet
func shoot():
	var bullet = bulletScene.instance()
	get_node("/root/MainScene").add_child(bullet)
	
	bullet.global_transform = muzzle.global_transform
	bullet.scale = Vector3.ONE
	
	ammo -= 1

	$SheepSound.play()

Bulet.gd

extends Area

var speed : float = 30.0
var damage: int = 1


# Called when the node enters the scene tree for the first time.
func _ready():
	pass # Replace with function body.


# Called every frame. 'delta' is the elapsed time since the previous frame.
func _process(delta):
	#move the bullet forward
	translation += global_transform.basis.z * speed * delta


func _on_Bullet_area_entered(body):
	if body.has_method('take_damage'):
		body.take_damage(damage)
		destroy()

func destroy():
	queue_free()

TwistedTwigleg

The easiest way is probably to take the direction from the center of the bullet to the collided body, and then flip it to get a bounce direction. You could also use Raycasting to get the collision normal, but it's a tad more complicated and may not be what you are looking for (as then it would bounce based on the shape rather than direction).

For the code, you will need to store the relative direction in a variable and then change it. Something like this should work for the bullet:

extends Area

var speed : float = 30.0
var damage: int = 1

# the direction the bullet will move towards
var movement_direction = Vector3.UP

# Called when the node enters the scene tree for the first time.
func _ready():
	movement_direction = global_transform.basis.z.normalized()

# Called every frame. 'delta' is the elapsed time since the previous frame.
func _process(delta):
	#move the bullet forward
	#translation += global_transform.basis.z * speed * delta
	
	# slight adjustment: move the bullet based on the movement_direction
	# variable and move the bullet's global (world-based) transform rather than
	# it's local one (which is based on the location of the parent node)
	# (This just makes sure it will work even if the parent node is rotated or moved)
	global_transform.origin += movement_direction * speed * delta

func _on_Bullet_area_entered(body):
	if body.has_method('take_damage'):
		body.take_damage(damage)
		destroy()
	# if we cannot damage, then bounce the bullet
	else:
		var self_to_body = global_transform.origin.direction_to(body.global_transform.origin)
		# use the opposite to bounce the bullet
		movement_direction = -self_to_body

func destroy():
	queue_free()