Attempt to call function 'connect' in base 'null instance' on a null instance

LuanSantos95

Hey guys, I have a little issue here: I'm trying to run my game and this error is informed: Attempt to call function 'connect' in base 'null instance' on a null instance. I searched the internet and most people said that the script is referring to a node that doesn't exist, so I tried to debug the code and I found out that the assign isn't showed. However, even after the assignment, the error persists. The code is right below:

extends Control
class_name InteractionComponentUI

export var interaction_component_nodepath : NodePath

export var interaction_texture_nodepath : NodePath
export var interaction_text_nodepath : NodePath
export var interaction_default_texture : Texture
export var interaction_default_text : String

var fixed_position : Vector2

func _ready():
	# We need to connect ourselves to the interaction components signal
	get_node(interaction_component_nodepath).connect("on_interactable_changed", self, "interactable_target_changed", [], CONNECT_DEFERRED)
	
	# On load we should be hidden
	hide()
	
func _process(delta : float):
	# Because we're a child of the player we'll always be moving relative to them
	# But when we're set against an item we should stick above it
	# So each frame we'll make sure we're moved to our fixed_position
	set_global_position(fixed_position)

func interactable_target_changed(newInteractable : Node) -> void:
	# If the new interactable thing is null it means we've moved out of range
	# Lets hide our UI
	if (newInteractable == null):
		hide()
		return
		
	# Otherwise, we've encountered something new
	# We want to get the icon we should display from it, along with the text
	
	# Start by grabbing our default texture & text
	var interaction_texture := interaction_default_texture
	var interaction_text := interaction_default_text
	
	# Then check whether the interactable has a custom texture
	if (newInteractable.has_method("interaction_get_texture")):
		interaction_texture = newInteractable.interaction_get_texture()
	
	# Or custom text
	if (newInteractable.has_method("interaction_get_text")):
		interaction_text = newInteractable.interaction_get_text()
	
	# We'll update our texture and text
	get_node(interaction_texture_nodepath).texture = interaction_texture
	get_node(interaction_text_nodepath).text = interaction_text
	
	# Record the position we should fix ourselves to
	# This should be just above the interactable item
	fixed_position = Vector2(newInteractable.get_global_position().x, newInteractable.get_global_position().y - 50)
	
	# Move to our fixed position
	self.set_global_position(fixed_position)
	
	# Then ensure we show ourselves
	show()

I used this video as reference:

I can share the zip file if it's needed.

The error is pointed at this line: get_node(interaction_component_nodepath).connect("on_interactable_changed", self, "interactable_target_changed", [], CONNECT_DEFERRED)

exuin

Well, the error tells us that there's something wrong with the variable interaction_component_nodepath but since it's an export variable I can't see the value of it. Do you have it assigned to anything?

LuanSantos95

@exuin said: Well, the error tells us that there's something wrong with the variable interaction_component_nodepath but since it's an export variable I can't see the value of it. Do you have it assigned to anything?

Not at this is script, but I'm trying to call another node. That script is from a node called "InteractComponentUI", and I'm trying to call from another node calle "InteractComponent". The "InteractComponent" script is right below:

extends Area2D

export var interaction_parent : NodePath

signal on_interactable_changed(newInteractable)

var interaction_target : Node

# Called every frame
func _process(delta):
	# Check whether the player is trying to interact
	if interaction_target != null and Input.is_action_just_pressed("interact"):
		# If so, we'll call interaction_interact() if our target supports it
		if (interaction_target.has_method("interaction_interact")):
			interaction_target.interaction_interact(self)


# Signal triggered when our collider collides with something on the interaction layer
func _on_InteractionComponent_body_entered(body):
	
	var canInteract := false
	
	# GDScript lacks the concept of interfaces, so we can't check whether the body implements an interface
	# Instead, we'll see if it has the methods we need
	if (body.has_method("interaction_can_interact")):
		# Interactables tell us whether we're allowed to interact with them.
		canInteract = body.interaction_can_interact(get_node(interaction_parent))
	
	if not canInteract:
		return
		
	# Store the thing we'll be interacting with, so we can trigger it from _process
	interaction_target = body
	emit_signal("on_interactable_changed", interaction_target)


func _on_InteractionComponent_body_exited(body):
	if (body == interaction_target):
		interaction_target = null
		emit_signal("on_interactable_changed", null)

So basically I'm trying to catch the signal from "InteractComponent", but it seems it is not finding its path.

TwistedTwigleg

Looking at the error, I think the issue is you need to set the exported NodePath in the first script, the one that is generating the error, since you attempt to get the node in the _ready function. If you go to the node in the Godot editor and select it, the inspector should show what the exported variable is set to. If it is not set to a node in the scene, then calling get_node will return null since there is no node there.

If you need to dynamically get the node and/or the node you need to get is not in the same scene, you will need to use a different solution to get the node than an exported NodePath. In this case, I would recommend putting the node(s) you want to get into a group and then using something likeget_tree().get_nodes_in_group("node_name")[0] to get the node. (Though I would recommend checking to make sure there are nodes in the group first, to avoid crashes if there isn't any or the nodes are initialized out of order)

LuanSantos95

@TwistedTwigleg said: Looking at the error, I think the issue is you need to set the exported NodePath in the first script, the one that is generating the error, since you attempt to get the node in the _ready function. If you go to the node in the Godot editor and select it, the inspector should show what the exported variable is set to. If it is not set to a node in the scene, then calling get_node will return null since there is no node there.

If you need to dynamically get the node and/or the node you need to get is not in the same scene, you will need to use a different solution to get the node than an exported NodePath. In this case, I would recommend putting the node(s) you want to get into a group and then using something likeget_tree().get_nodes_in_group("node_name")[0] to get the node. (Though I would recommend checking to make sure there are nodes in the group first, to avoid crashes if there isn't any or the nodes are initialized out of order)

So even if I call a node by its path, with "connect()" function I still won't be able to do so?

TwistedTwigleg

@LuanSantos95 said:

@TwistedTwigleg said: Looking at the error, I think the issue is you need to set the exported NodePath in the first script, the one that is generating the error, since you attempt to get the node in the _ready function. If you go to the node in the Godot editor and select it, the inspector should show what the exported variable is set to. If it is not set to a node in the scene, then calling get_node will return null since there is no node there.

If you need to dynamically get the node and/or the node you need to get is not in the same scene, you will need to use a different solution to get the node than an exported NodePath. In this case, I would recommend putting the node(s) you want to get into a group and then using something likeget_tree().get_nodes_in_group("node_name")[0] to get the node. (Though I would recommend checking to make sure there are nodes in the group first, to avoid crashes if there isn't any or the nodes are initialized out of order)

So even if I call a node by its path, with "connect()" function I still won't be able to do so?

Yes and no. You need to get the node first, and then call connect on it. The problem seems to be that get_node(interaction_component_nodepath) is null, so calling connect right after is having it attempt to call the function on null, which results in the error. The issue is likely that the interaction_component_nodepath variable is not pointing to a node in the scene, so when get_node tries to get the node at the NodePath in interaction_component_nodepath it cannot find it and returns null. Setting interaction_component_nodepath in the Godot editor by clicking the node and setting the value in the inspector, should fix the issue.