currently having problems with match statement

BorgyDudeMan

so i tried to do some stuff with the match statement here:

func _onProfileSwitchButton_pressed():
	file = File.new()
	file.open("res://save_data.json", File.READ)
	json_data = JSON.parse(file.get_as_text())
	file.close()
	save_data = json_data.result
	
	print(profileNum)

	match profileNum:
		0:
			print("zero")
		1:
			print("one")
		2:
			print("two")
		3:
			print("three")
		4:
			print("four")

only problem is that it doesnt output anything. profileNum has already been declared in _func ready() btw...

vmjcv

	extends Node2D
	
	var profileNum
	
	func _ready():
		profileNum=0
		_onProfileSwitchButton_pressed()
	
	func _onProfileSwitchButton_pressed():
		match profileNum:
			0:
				print("zero")
			1:
				print("one")
			2:
				print("two")
			3:
				print("three")
			4:
				print("four")

i test it , it can print zero

BorgyDudeMan

@BorgyDudeMan said: so i tried to do some stuff with the match statement here:
func _onProfileSwitchButton_pressed():
	file = File.new()
	file.open("res://save_data.json", File.READ)
	json_data = JSON.parse(file.get_as_text())
	file.close()
	save_data = json_data.result
	
	print(profileNum)

	match profileNum:
		0:
			print("zero")
		1:
			print("one")
		2:
			print("two")
		3:
			print("three")
		4:
			print("four")
only problem is that it doesnt output anything. profileNum has already been declared in _func ready() btw...

should have also added how profileNum was defined:

var playPressable = true
var settingsPressable = true
var exitPressable = true
var profilePressable = true
var playerName
var profileNum
var file
var data
var json_data
var save_data

func _ready():
	# make most of the buttons unpressable
	playPressable = false
	settingsPressable = false
	exitPressable = false
	profilePressable = false
	
	# get the save file
	file = File.new()
	file.open("res://save_data.json", File.READ)
	data = file.get_as_text()
	json_data = JSON.parse(data)
	file.close()
	save_data = json_data.result["data"]
	profileNum = json_data.result["profileNum"]
	
	if save_data.count(null) == 5:
		# if the save file is empty, open the prompt that will allow for creation of a new profile
		$NewProfileMaker.show()
		$NewProfileMaker/Control/ProfileMakerExit.hide()
	else:
		# when a save file is filled up, collect stuff about the last chosen profile
		playerName = save_data[profileNum]["name"]
		print(profileNum)
		$ChangeProfile/ProfileName/Label.text = playerName
		
		# fill up all the available profile names
		for n in range(5):
			if n < save_data.size() - save_data.count(null):
				# for available profiles
				get_node("ProfilePanel/Control/ProfileList/Profile"+str(n)+"/Button").text = save_data[n]["name"]
			else:
				# for unavailable profiles
				get_node("ProfilePanel/Control/ProfileList/Profile"+str(n)+"/Button").disabled = true
		
		# make buttons pressable again
		playPressable = true
		settingsPressable = true
		exitPressable = true
		profilePressable = true

vmjcv

you need change profileNum type like this ,i t can print zero

	extends Node2D
	
	var profileNum
	var file
	var data
	var json_data
	
	func _ready():
		file = File.new()
		file.open("res://save_data.json", File.READ)
		data = file.get_as_text()
		json_data = JSON.parse(data)
		file.close()
		profileNum = int(json_data.result["profileNum"])
		_onProfileSwitchButton_pressed()
	
	func _onProfileSwitchButton_pressed():
		match profileNum:
			0:
				print("zero")
			1:
				print("one")
			2:
				print("two")
			3:
				print("three")
			4:
				print("four")

this is json data { "profileNum": 0, }

vmjcv

because the json type just number,not float and int ,so the godot parse json data to float