How do I perform an action once when my kinematicbody2D lands on a platform?

mjpatey

Hi!

I'm relatively new to Godot and to modern programming in general (my main experience was as a teenager writing games in BASIC on a C64). My son and I are learning Godot, and making a platformer as a first Godot project.

So my character is a KinematicBody2D, and my platform is a StaticBody2D. At the end of a jump, when my character lands on the platform, I want it to squish down then return to normal, which I'm using scale.y to accomplish.

The problem is, I'm not sure how to detect that the character has "just" landed. I've tried using is_on_floor, but of course that triggers the squish continually for as long as the character is on the floor.

I tried adding an Area2D to the feet of the character and using on_body_entered, but it would only detect the platform the first time the character landed (then nothing from that point on). And it would occasionally complain and stop the program with an error saying I'm referring to a null object after running for a few minutes. I got sleepy and stopped after this.

How do I isolate that moment of landing at the end of a jump, and do a little scaling down and back up again?

Thanks in advance for any light you can shed!

-Mark

TwistedTwigleg

Welcome to the forums @mjpatey!

One way you can detect if the player has just hit the ground is by setting a boolean to true when is_on_floor() is false, or when the player jumps if you want the effect to only occur after a jump. Then, to tell if the ground hit has occurred, you can check to see if is_on_floor is true and if the boolean you made is true. If both are true, then the player has been in the area (the boolean) and has now just hit the ground (is_on_floor). Then you can do whatever code you need for the squish, and at the end of the condition, set the boolean to false, as the player has collided with the ground.

In code (untested):

extends KinematicBody2D

# the boolean we'll use
var is_in_air = false

func _physics_process(delta):
	# If the character is in the air...
	if (is_on_floor() == false):
		# set the boolean that shows the character is in the air
		is_in_air = true
	# if the character is on the ground...
	else:
		# was the player in the air?
		if (is_in_air == true):
			# the player just hit the ground this physics frame!
			# Do whatever effects are needed here
			print ("Just hit ground!")
			# make sure to set is_in_air to false, so the code is only called
			# once.
			is_in_air = false

gonz4-l

This worked to me:

extends KinematicBody2D


const UP = Vector2(0, -1)
const GRAVITY = 35
const SPEED = 700
const JUMP_HEIGHT = -1200

var motion = Vector2()
var motion_previous = Vector2()

var hit_the_ground = false

func _physics_process(delta):
	motion_previous = motion
	motion = move_and_slide(motion, UP, false)
	
	
	"""
	-- New Code from this Point --
	If the player is in the air, make scale of sprite
	based on the y motion value using range_lerp
	The fast the y motion, 
	the larger the y stretch, 
	the larger the x squash
	"""
	
	if not is_on_floor():
		hit_the_ground = false
		$Sprite.scale.y = range_lerp(abs(motion.y), 0, abs(JUMP_HEIGHT), 0.75, 1.75)
		$Sprite.scale.x = range_lerp(abs(motion.y), 0, abs(JUMP_HEIGHT), 1.25, 0.75)
	
	"""
	If there's a floor collision,
	set squashed scale values based on
	previous motion
	"""
	
	if not hit_the_ground and is_on_floor():
		hit_the_ground = true
		$Sprite.scale.x = range_lerp(abs(motion_previous.y), 0, abs(1700), 1.2, 2.0)
		$Sprite.scale.y = range_lerp(abs(motion_previous.y), 0, abs(1700), 0.8, 0.5)
	
	$Sprite.scale.x = lerp($Sprite.scale.x, 1, 1 - pow(0.01, delta))
	$Sprite.scale.y = lerp($Sprite.scale.y, 1, 1 - pow(0.01, delta))

Don't ask me why the character it's a door. XD

mjpatey

@TwistedTwigleg @"Gonz4 L" thanks so much! The thing I hadn't done yet was to set a boolean that immediately gets turned off once the character lands and begins the squish.

I really appreciate the time you both took to explain and even demonstrate the solution. What a great group!

mjpatey

@"Gonz4 L" OK, I'm seriously impressed with your squash & stretch technique. Mine currently does a one-size-fits-all stretch when the jump starts, and so far, no squash at the end (about to implement the boolean technique you and Twisted described)... but I love the look of yours! Was this just off the top of your head, or something you've used before? Impressive either way, and thanks for sharing.

I searched for a bit and couldn't find enough about range_lerp to make sense of it yet, but I'm going to try your code and see if I can tweak it to better understand what makes it tick. I understand how to use regular lerp, which I would have tried to use for this.

Thanks again!

gonz4-l

@mjpatey I just googled your question and appeared to me a video made by JohnnyGossDev (explanation in 1:00):

I'm still learning godot, so if it weren't for that video I wouldn't have been able to do it (all credits to the author). Hope it helps!

mjpatey

@"Gonz4 L" that is very cool. Funny, it never occurred to me to Google the exact thing I was trying to do. I was more focused on getting anything to happen immediately upon landing. But there it is. Thanks again!