How can i adapt my character's coordinates to the flipped tilemap ones?

gonz4-l

When you press certain buttons in my game, the tilemap (with enemies and objects that touch the ground but without the player) is flipped horizontally or vertically. To make it, i did this:

extends Node2D


func _process(delta):
	if Input.is_action_just_pressed("ui_accept"): #For now "ui_accept".
		if $TileMap.scale.y == 1:
			$TileMap.scale.y = -1
		else:
			$TileMap.scale.y = 1
	if Input.is_action_just_pressed("ui_cancel"):  #The same as before.
		if $TileMap.scale.x == 1:
			$TileMap.scale.x = -1
		else:
			$TileMap.scale.x = 1

But there's a problem:

When my tilemap it's flipped horizontally, vertically or both, the coordinates of the player don't coincide with the sprite and collision shape (because is not flipped along with my tilemap) so my game detects if the player is stuck in tiles i.e in -23, 22 instead of 22, -23 like it should be. I tried this:

var a = $TileMap.world_to_map($Player.get_position() - Vector2(-1820, 896))
var b = $TileMap.get_cellv(a)
print(a)

But when i move forward, character's x position it's 21 when it should be 23 (the same vertically). Is there a way to flip the coordinates and not my character along with the tilemap?

Megalomaniak

Have a flipped state implemented? Then check against it in every relevant operation?

gonz4-l

Sorry, I don't really understand what you say. With this code:

var a = $TileMap.world_to_map($Player.get_position() - Vector2(-1820, 896) #Adaptation of player's start position)

I managed to adapt the coordinates of the character that the tilemap detects with its true position when the game starts. But when i move, the coordinates fail again (open image in new tab to see better): (21, -23) it's the fake position of the player and (23, -23) the real one. Now i tried this: But neither can Vector2 be added and subtracted nor do I think it's fine "if $Player.position.x + 1 / y - 1:" (Well, i don't even know how well i write in English). How could i do it right?

Megalomaniak

Honestly not sure what you are trying to do exactly or why? Maybe explain what and why and someone might be able to offer a solution.

gonz4-l

I'll try to give as much information as i can. Only the tilemap is flipped because then you can obtain objects originally out of your range, avoid enemies (if they're in the ground), get to the room's exit (my game is based on them), etc. (open image in new tab to see better).

I maked it using scale.y/x = -1:

extends Node2D


func _process(delta):
	if Input.is_action_just_pressed("ui_accept"):
		if $TileMap.scale.y == 1: #Normal state.
			$TileMap.scale.y = -1 #Flipped_v state.
			$Label2.set_text("Flipped_v = true")
		else:
			$TileMap.scale.y = 1
			$Label2.set_text("Flipped_v = false")
	if Input.is_action_just_pressed("ui_cancel"):
		if $TileMap.scale.x == 1:
			$TileMap.scale.x = -1 #Flipped_h state.
			$Label.set_text("Flipped_h = true")
		else:
			$TileMap.scale.x = 1
			$Label.set_text("Flipped_h = false")

But because my character it's not flipped along with the tilemap, it can get stuck in tiles:

So i tried this (thanks to @TwistedTwigleg):

var  P_pos = $TileMap.world_to_map($Player.get_position()) #Transforms player's position in pixels to cells.
var P_stuck_in_tiles = $TileMap.get_cellv(P_pos)
if P_stuck_in_tiles != -1: #-1 = no tile.
	$Player.position.y -= 80 #Pixels (My tiles are 40x20  instead of 32x32 because being the tilemap origin in the center of the screen gives me problems and i still prefer my game being 16:9(1920, 1080)).
print(b)

It works well if tilemap it's in normal state:

But in the rest of states (flipped_v, flipped_h and both_on)... either happens this:

or:

So i analized the coordinates of P_pos if they were different to what i wanted and, yes, it was that but i decided to draw a red circle in my character's position in case that makes it more understandable:

The problem is that even if my kinematicbody2d isn't a children of tilemap, this last one still always conserves player's original position like if it was (the player's coordinates will always be (-23, 22), (-19, 10), (20, 9), etc. no matter in which state the tilemap it's): It's like this but without the sprite and collision shape flipping along with the kinematicbody's position: It's not my game's idea.

What i want it's this (in text): ^Normal (P_pos = (-23, 22), (-19, 10), (20, 9), etc). ^Flipped_h (P_pos = (22, 22), (10, 10), (9, 9), etc). ^Flipped_v (P_pos = (-23, -23), (-19, -19),(20, 20), etc). ^Both_on (P_pos = (22, -23), (10, -19), (9, 20), etc).

My nearest try:

extends Node2D


var F_V = false #Flipped_v
var F_H = false #Flipped_h
var B_O = 0  #Both_on

func _process(delta):
	if Input.is_action_just_pressed("ui_accept"):
		if F_V == false:
			$TileMap.scale.y = -1
			F_V = true
			B_O += 1
			$Label2.set_text("Flipped_v = true")
		else:
			$TileMap.scale.y = 1
			F_V = false
			B_O -= 1
			$Label2.set_text("Flipped_v = false")
	if Input.is_action_just_pressed("ui_cancel"):
		if F_H == false:
			$TileMap.scale.x = -1
			F_H = true
			B_O += 1
			$Label.set_text("Flipped_h = true")
		else:
			$TileMap.scale.x = 1
			F_H = false
			B_O -= 1
			$Label.set_text("Flipped_h = false")
	
        var P_pos 
	var Difference_B_O = Vector2(-1820, 896)
	var Difference_F_H = Vector2(-1820, 0)
	var Difference_F_V = Vector2(0, 896)
	if F_H == true:
		P_pos = $TileMap.world_to_map($Player.get_position() - Difference_F_H)
	if F_V == true:
		P_pos = $TileMap.world_to_map($Player.get_position() - Difference_F_V)
	if B_O == 2:
		P_pos = $TileMap.world_to_map($Player.get_position() - Difference_B_O)
	if B_O == 0:
		P_pos = $TileMap.world_to_map($Player.get_position())
	var P_stuck_in_tiles = $TileMap.get_cellv(P_pos)
	if P_stuck_in_tiles != -1:
		$Player.position.y -= 4
	$Label3.set_text("Cell =" + " " + str(P_pos) + " " + str(P_stuck_in_tiles))

:) :( I hope this serves more.

Megalomaniak

So it looks like you might have a bit of a precision error? i.e. 22 becoming -23 after the flip?

gonz4-l

No, that's what i want; what i don't like it's this (i used the circle again to mark player's position):

My idea it's to adapt player's position in the flipped tilemap states like if they were the normal state (that's why i said (x = -23, y = 22), (22, 22), (-23, -23) and (22, -23) respectively) (circles again): ^ In this gif the adaptation works wells but as i move one or more cells... (praise God Circle):

Has more logic this images now?

My new best try:

#Diff_B_O = Flipped_h and Flipped_v == true
func _on_Area2D_area_entered(area):
	Diff_B_O = Vector2(-1740, 896) #(21, -23)
	Diff_F_H = Vector2(-1740, 0)
	Diff_F_V = Vector2(0, 896)

func _on_Area2D2_area_entered(area):
	Diff_B_O = Vector2(-1860, 896) #(23, -23)
	Diff_F_H = Vector2(-1860, 0)
	Diff_F_V = Vector2(0, 896)

func _on_Area2D3_area_entered(area):
	Diff_B_O = Vector2(-1820, 856) #(22, -22)
	Diff_F_H = Vector2(-1820, 0)
	Diff_F_V = Vector2(0, 856)

func _on_Area2D4_area_entered(area):
	Diff_B_O = Vector2(-1660, 896) #(20, -23)
	Diff_F_H = Vector2(-1660, 0)
	Diff_F_V = Vector2(0, 896)

func _on_Area2D5_area_entered(area):
	Diff_B_O = Vector2(-1820, 896) #(22, -23)
	Diff_F_H = Vector2(-1820, 0)
	Diff_F_V = Vector2(0, 896)

But still doesn't works well (apart from not being the best to have 500 areas):

Basically, i think, what i want to know it's: how can i get the difference between the origin of tilemap (0, 0) and my character's position (-920, 450 when start (I don't know how it should be in the flipped states) ) every frame?

gonz4-l

Megalomaniak

@"Gonz4 L" said:

When my tilemap it's flipped horizontally, vertically or both, the coordinates of the player don't coincide with the sprite and collision shape (because is not flipped along with my tilemap) so my game detects if the player is stuck in tiles i.e in -23, 22 instead of 22, -23 like it should be. I tried this:
var a = $TileMap.world_to_map($Player.get_position() - Vector2(-1820, 896))
var b = $TileMap.get_cellv(a)
print(a)
But when i move forward, character's x position it's 21 when it should be 23 (the same vertically). Is there a way to flip the coordinates and not my character along with the tilemap?

Ok, rereading the opening post, one thing that jumps out at me that is worth noting is that you can flip/scale nodes all you want but it does not change coordinates in the scene as a whole since the scene origin has not been modified/manipulated.

Now when I say scene I mean the runtime scenegraph/scene tree. There is only one.

But when i move forward, character's x position it's 21 when it should be 23 (the same vertically). Is there a way to flip the coordinates and not my character along with the tilemap?

Now for the tilemap specifically, what coordinates a tile within it ends up at depends on the dimensions of the tilemap and its tiles as well as where the origin/pivot point of the tilemap is. Assuming that your character is not a child of the tilemap, the characters coordinates nor its orientation will be affected what so ever when the tilemap is flipped/scaled.

I guess what I'm saying is that you will want to very carefully pay attention to where your tilemaps origin point is in respect to itself and the same respectively for the character.

---

As for the issue of avoiding the character getting stuck when the tilemap has been flipped, it is and should be handled as a separate issue from the tilemaps flipping. And you will likely need a specialized solution.

gonz4-l

@Megalomaniak said: As for the issue of avoiding the character getting stuck when the tilemap has been flipped, it is and should be handled as a separate issue from the tilemaps flipping. And you will likely need a specialized solution.

Well... i think the best i can do it's to make a tilemap for each state (4 in total) with scale 1, 1 and activate and disable them respectively (it's tedious, but at least works):

#1 = Normal
#2 = F_H
#3 = F_V
#4 = B_O

After doing that, I'll see if I continue with the project (my second game) or finish a much simpler one first (i already have a good idea so...). .................................................................................................................................................................................................................................. Thank you very much for your attention!

TwistedTwigleg

You might be able to make a tool script that takes a TileMap (or is attached to a TileMap) and makes and adds 4 copies, one for each state, of the TileMap to the scene. It would potentially reduce some of the tediousness of copying the map by hand for each state.

Something like this (untested):

tool
extends TileMap
export(bool) var editor_make_copies = false setget editor_make_copies 

# Note: this is in tile coordinates, not world coordinates
export (Vector2) var tilemap_top_left_corner = Vector2(0, 0)
export (Vector2) var tilemap_bottom_right_corner = Vector2(10, 10)

func _ready():
	pass

func make_tilemap_copies():
	# make a 2D array of tiles
	var tiles = []
	for (int x = tilemap_top_left_corner .x; x < tilemap_bottom_right_corner.x; x++):
		var tile_row = []
		for (int y = tilemap_top_left_corner.y; y < tilemap_bottom_right_corner.y; y++):
			tile_row.append(get_cell(x, y))
		tiles.append(tile_row)
	
	# make a copy of the original (no tile manipulation needed!)
	var tilemap_state_01 = self.duplicate()
	tilemap_state_01 = self.name + "_state01"
	add_child(tilemap_state_01)
	# you may need to add the owner... I cannot remember right off
	# tilemap_state_01.set_owner(self.get_owner())
	
	# make a copy mirrored on the X axis
	var tilemap_state_02 = self.duplicate()
	tilemap_state_02 = self.name + "_state02"
	#
	for (int x = 0; x< tilemap_bottom_right_corner.x - tilemap_top_left_corner.x; x++):
		for (int y = 0; y < tilemap_bottom_right_corner.y - tilemap_top_left_corner.y; y++):
			# The coordinates of the tile we are going to set
			var set_coordinates_x = tilemap_top_left_corner.x + x
			var set_coordinates_y = tilemap_top_left_corner.y + y
			# The coordinates of the tile we are going to copy
			# (only mirroring the X axis for this one)
			var copy_coordinates_x = tilemap_top_right_corner.x - x
			var copy_coordinates_y = tilemap_top_left_corner.y + y
			
			tilemap_state_02.set_cell(set_coordinates_x, set_coordinates_y, get_tile(copy_coordinates_x, copy_coordinates_y)
	add_child(tilemap_state_02)
	
	# make a copy mirrored on the Y axis
	var tilemap_state_03 = self.duplicate()
	tilemap_state_03 = self.name + "_state03"
	#
	for (int x = 0; x< tilemap_bottom_right_corner.x - tilemap_top_left_corner.x; x++):
		for (int y = 0; y < tilemap_bottom_right_corner.y - tilemap_top_left_corner.y; y++):
			# The coordinates of the tile we are going to set
			var set_coordinates_x = tilemap_top_left_corner.x + x
			var set_coordinates_y = tilemap_top_left_corner.y + y
			# The coordinates of the tile we are going to copy
			# (only mirroring the Y axis for this one)
			var copy_coordinates_x = tilemap_top_left_corner.x + x
			var copy_coordinates_y = tilemap_top_right_corner.y - y 
			
			tilemap_state_03.set_cell(set_coordinates_x, set_coordinates_y, get_tile(copy_coordinates_x, copy_coordinates_y)
	add_child(tilemap_state_03)

	# make a copy mirrored on the X and Y axis
	var tilemap_state_04 = self.duplicate()
	tilemap_state_04 = self.name + "_state04"
	#
	for (int x = 0; x< tilemap_bottom_right_corner.x - tilemap_top_left_corner.x; x++):
		for (int y = 0; y < tilemap_bottom_right_corner.y - tilemap_top_left_corner.y; y++):
			# The coordinates of the tile we are going to set
			var set_coordinates_x = tilemap_top_left_corner.x + x
			var set_coordinates_y = tilemap_top_left_corner.y + y
			# The coordinates of the tile we are going to copy
			var copy_coordinates_x = tilemap_top_right_corner.x - x 
			var copy_coordinates_y = tilemap_top_right_corner.y - y 
			
			tilemap_state_04.set_cell(set_coordinates_x, set_coordinates_y, get_tile(copy_coordinates_x, copy_coordinates_y)
	add_child(tilemap_state_04)
	
	print ("Editor: TileMap states have been processed and added as children!")
	

func editor_make_copies (_value):
	editor_make_copies = false
	make_tilemap_copies()

gonz4-l

@TwistedTwigleg Sorry, there's a problem with for in your code.

TwistedTwigleg

@"Gonz4 L" said: @TwistedTwigleg Sorry, there's a problem with for in your code.

My bad! I was writing for loops using C++ syntax, not GDScript. Here's the replacement for the various for loops in the above code:

Lines 15-17:

for x in range(tilemap_top_left_corner.x, tilemap_bottom_right_corner.x):
	var tile_row = []
	for y in range(tilemap_top_left_corner.x, tilemap_bottom_right_corner.y):

Lines 32-33, 49-50, and 66-67:

for x in range(0, tilemap_bottom_right_corner.x - tilemap_top_left_corner.x):
	for y in range(0, tilemap_bottom_right_corner.y - tilemap_top_left_corner.y):

That should fix all of the for loops. :+1:

gonz4-l

@TwistedTwigleg Thanks! it worked for the code, the only problem now it's that Godot crash:

Maybe because it's flipping an infinite amount of cells?

TwistedTwigleg

@"Gonz4 L" said: @TwistedTwigleg Thanks! it worked for the code, the only problem now it's that Godot crash:

Maybe because it's flipping an infinite amount of cells?

Possibly? There is a lot of things it could be, and unfortunately when Godot just crashes its hard to debug the issue. I would suggest commenting out all of the code that copies the tilemap, and slowly introduce each copy one by one until you find the snippet that seems to be causing the crash.

If there is time, I can see if I have a project with a Tilemap and do some debugging myself later.

TwistedTwigleg

Alright, I took some time to debug what was happening and fix a bunch of issues. The crash was caused due to a stackoverflow, which happened because the script attached to the TileMap was copied as well. Because of how the setget code was written, it would cause the copies to also try to copy themselves, eventually filling the stack and causing the crash.

However, even after fixing that issue, the script was not copying the map correctly. After some more debugging, I got something that seems to be working in my testing. Here's the script (I've also attached it as a file):

tool
extends TileMap
export(bool) var editor_make_copies = false setget func_editor_make_copies 

# Note: this is in tile coordinates, not world coordinates
export (Vector2) var tilemap_top_left_corner = Vector2(0, 0)
export (Vector2) var tilemap_bottom_right_corner = Vector2(10, 10)

func _ready():
	if (Engine.editor_hint == false):
		make_tilemap_copies();

func make_tilemap_copies():
	# make a 2D array of tiles
	var tiles = []
	for x in range(tilemap_top_left_corner.x, tilemap_bottom_right_corner.x):
		var tile_row = []
		for y in range(tilemap_top_left_corner.y, tilemap_bottom_right_corner.y):
			tile_row.append(get_cell(x, y))
		tiles.append(tile_row)
	
	# ==========================================================================
	# FIRST COPY - Just a normal copy, no mirroring
	
	var tilemap_state_01 = make_duplicate_tilemap();
	tilemap_state_01.name = self.name + "_state01"
	
	for x in range(0, tilemap_bottom_right_corner.x - tilemap_top_left_corner.x):
		for y in range(0, tilemap_bottom_right_corner.y - tilemap_top_left_corner.y):
			
			# The coordinates of the tile we are going to set
			var set_coordinates_x = tilemap_top_left_corner.x + x
			var set_coordinates_y = tilemap_top_left_corner.y + y
			tilemap_state_01.set_cell(set_coordinates_x, set_coordinates_y, get_cell(set_coordinates_x, set_coordinates_y));
	
	add_child(tilemap_state_01)
	tilemap_state_01.set_owner(self.get_owner())
	
	# ==========================================================================
	
	# ==========================================================================
	# SECOND COPY - The same tilemap, but mirrored on the X axis
	
	var tilemap_state_02 = make_duplicate_tilemap();
	tilemap_state_02.name = self.name + "_state02"
	
	for x in range(0, tilemap_bottom_right_corner.x - tilemap_top_left_corner.x):
		for y in range(0, tilemap_bottom_right_corner.y - tilemap_top_left_corner.y):
			
			# The coordinates of the tile we are going to set
			var set_coordinates_x = tilemap_top_left_corner.x + x
			var set_coordinates_y = tilemap_top_left_corner.y + y
			
			# The coordinates of the tile we are going to copy
			# (only mirroring the X axis for this one)
			var copy_coordinates_x = tilemap_bottom_right_corner.x - x - 1;
			var copy_coordinates_y = set_coordinates_y;
			
			tilemap_state_02.set_cell(set_coordinates_x, set_coordinates_y, get_cell(copy_coordinates_x, copy_coordinates_y));
	
	add_child(tilemap_state_02)
	tilemap_state_02.set_owner(self.get_owner())
	
	# ==========================================================================
	
	# ==========================================================================
	# THIRD COPY - The same tilemap, but mirroed on the Y axis
	
	var tilemap_state_03 = make_duplicate_tilemap();
	tilemap_state_03.name = self.name + "_state03"
	
	for x in range(0, tilemap_bottom_right_corner.x - tilemap_top_left_corner.x):
		for y in range(0, tilemap_bottom_right_corner.y - tilemap_top_left_corner.y):
			
			# The coordinates of the tile we are going to set
			var set_coordinates_x = tilemap_top_left_corner.x + x
			var set_coordinates_y = tilemap_top_left_corner.y + y
			
			# The coordinates of the tile we are going to copy
			# (only mirroring the Y axis for this one)
			var copy_coordinates_x = set_coordinates_x;
			var copy_coordinates_y = tilemap_bottom_right_corner.y - y - 1;
			
			tilemap_state_03.set_cell(set_coordinates_x, set_coordinates_y, get_cell(copy_coordinates_x, copy_coordinates_y));
	
	add_child(tilemap_state_03)
	tilemap_state_03.set_owner(self.get_owner())
	
	# ==========================================================================
	
	# ==========================================================================
	# FOUTH COPY - The same tilemap, but mirrored on both the X and Y axes
	
	var tilemap_state_04 = make_duplicate_tilemap();
	tilemap_state_04.name = self.name + "_state04"
	
	for x in range(0, tilemap_bottom_right_corner.x - tilemap_top_left_corner.x):
		for y in range(0, tilemap_bottom_right_corner.y - tilemap_top_left_corner.y):
			
			# The coordinates of the tile we are going to set
			var set_coordinates_x = tilemap_top_left_corner.x + x
			var set_coordinates_y = tilemap_top_left_corner.y + y
			
			# The coordinates of the tile we are going to copy (X and Y)
			var copy_coordinates_x = tilemap_bottom_right_corner.x - x - 1;
			var copy_coordinates_y = tilemap_bottom_right_corner.y - y - 1;
			
			tilemap_state_04.set_cell(set_coordinates_x, set_coordinates_y, get_cell(copy_coordinates_x, copy_coordinates_y));
	
	add_child(tilemap_state_04)
	tilemap_state_04.set_owner(self.get_owner())
	
	# ==========================================================================
	
	print ("Editor: TileMap states have been processed and added as children!")


func make_duplicate_tilemap():
	var return_map = TileMap.new();
	return_map.tile_set = tile_set;
	# Anything else you need to copy, add it here!
	return return_map;


func func_editor_make_copies (_value):
	if (_value == true):
		make_tilemap_copies()
	editor_make_copies = false

And here is the file:

gonz4-l

@TwistedTwigleg Thank you very much for solving such a complex issue, i appreciate your effort!

TwistedTwigleg

@"Gonz4 L" said: @TwistedTwigleg Thank you very much for solving such a complex issue, i appreciate your effort!

No problem, happy to help! :smile: