problem with Vector2 in move_and_collide()

UnknownUser

Hey guys,

I made a simple enemy node. It works ok for changing direction every frame, but for some reason whenever I don't change Vector2 Variable inside the _process function Godot seems to treat it as an Object class instance and spits error: "Invalid operands 'Object' and 'float' in operator '*'.".

I don't really understand why this is since it's already defined onready variable. I would like to change directions only when timer times out, could you please tell me where is my mistake here?

here is my code:

extends KinematicBody2D


export var speed= 300

onready var dir= Vector2(1, 1)


func _ready():
	get_input()
	pass

func _process(delta):	
	get_input()
	dir= move_and_collide(dir*delta)	
	pass
	
	


	
func get_input():
	var player_dir= Vector2.ZERO
	if(randf()> 0.5):
		player_dir.x= randf()
	else:
		player_dir.x= -randf()
	if(randf()> 0.5):
		player_dir.y= randf()
	else:
		player_dir.y= -randf()

	dir= player_dir.normalized()* speed
	pass



func _on_Area2D_area_entered(_area):
	queue_free()
	pass


func _on_Timer_timeout():
	get_input()
	pass

UnknownUser

Megalomaniak

This discussion was caught in the moderation queue since you have not confirmed your account yet.

Upon creating your account you should have received an account verification email. The confirmation email may have been incorrectly flagged as spam, so please also check your spam filter. Without confirming your account, future posts may also be caught in the moderation queue. You can resend a confirmation email when you log into your account if you cannot find the first verification email.

If you need any help, please let us know! You can find ways to contact forum staff on the Contact page. Thanks! :smile:

cybereality

So, move_and_collide returns a KinematicCollision2D, not a Vector2. Since you are setting dir directly in your get_input function, you don't need the assignment. Also, you don't have to put pass at the end of every function. It is only needed if the function is empty. Here is the working code.

extends KinematicBody2D

export var speed = 300
var dir = Vector2(1, 1)

func _ready():
	get_input()
	
func _process(delta):   
	move_and_collide(dir * delta)    
	
func get_input():
	var player_dir = Vector2.ZERO
	if (randf() > 0.5):
		player_dir.x = randf()
	else:
		player_dir.x = -randf()
	if (randf() > 0.5):
		player_dir.y = randf()
	else:
		player_dir.y = -randf()
	dir = player_dir.normalized() * speed
	
func _on_Area2D_area_entered(_area):
	queue_free()
	
func _on_Timer_timeout():
	get_input()

UnknownUser

this solves my problem, thank you!

cybereality

Awesome! So happy I could help.