append Polygon2D.polygon ?

UnknownUser

And another newbie question. Is it correct that a Polygon2D.polygon can only be changed but not appended? Here's an example:

extends Node2D


func _ready() -> void:
	randomize()


func draw_random_triangle() -> void:
	var viewportSize := get_viewport().size
	var polygon := PoolVector2Array()

	for _i in range( 3 ):
		polygon.append( Vector2( randi() % int( viewportSize.x ), randi() % int( viewportSize.y ) ) )

	( $Shape as Polygon2D ).color = Color( randf(), randf(), randf() )
	( $Shape as Polygon2D ).polygon = polygon
	( $Shape as Polygon2D ).polygon.append( Vector2( 50, 50 ) ) # <--- this does nothing


func _process( _delta:float ) -> void:
	draw_random_triangle()

The last line of draw_random_triangle() does nothing, not even increase the array size, and there's no error or warning. So a Polygon2D.polygon seems locked and unchangeable. However, I can draw a new polygon if I simply give the property a brand new PoolVector2Array value. I'm just wondering if I can in some way append $Shape.polygon itself and maybe force a redraw, but I couldn't find a way to do that. No problem if that's simply not possible, it's easy enough to work around it, but well, I'm trying to learn …

bitshift-r

Modifying the shape.polygon doesn't work because when you access it you're actually getting a copy of the shape's polygon array. There's a mention in the PoolVector2Array docs about it being passed by value and not by reference. Reassigning the polygon is the only way to update it when adding or removing points. However it is possible to modify the elements in the array without reassigning:

var polygon = shape.polygon

polygon.resize(4)
polygon.set(0, Vector2(0.0, 0.0))
polygon.set(1, Vector2(50.0, 0.0))
polygon.set(2, Vector2(50.0, 50.0))
polygon.set(3, Vector2(0.0, 50.0))

shape.polygon = polygon

shape.polygon[3].y = 200.0  # this works

I use something like this to add/remove elements:

var new_polygon = shape.polygon
new_polygon.append(Vector2(25.0, 75.0))
new_polygon.append(Vector2(0.0, 75.0))
shape.polygon = new_polygon

UnknownUser

Thanks again. I must've missed the "being passed by value and not by reference" bit, with that I understand why it behaves the way it does. So for any modification I do it outside the Polygon2D property and then just reassign the value. Thank you!