Picking item up wont work, please help me figure out why.

UnknownUser

Hello I've been playing around with top-down 2D to learn and ultimately make my own game, already learned a ton and could understand and solve many hurdles, but now i've been stuck on this for the last day.

Basically i'm trying to be able to pick up weapons that are on the floor by standing on them and pressing right click. This changes the character sprite and "deletes" the weapon on the floor (It will later add a node to the player character with the weapon and it's functionalities but that's not there yet)

I have a player node with an Area2D, a weapon on the ground node with an Area2D, there's a signal on the player for "area_entered" and it is working since the console prints "Pistol (pickup) when i stand on it, but then right clicking does nothing.

func _on_Area2D_area_entered(area):
	print(area.name)
	if area.name == "Pistol (pickup)" and Input.is_action_just_pressed("rclick"):
		$Sprite.set_texture(con_pistola)
		area.queue_free()

It's written like this so i can later add a block like that for each weapon.

(The texture "con_pistola" is preloaded earlier in the code, and i tested with some simple lines for "right click to change the character sprite" with it and it worked)

What's wrong? :#

Thanks in advance!

Megalomaniak

You might have to include type identification for that string(the area.name == string("Pistol (pickup)") and its quite possible that the node in runtime has a different name altogether. You can check the scene tree and see it has a 'remote' option that lets you explore the scene tree of the running game when it has been launced from editor.

UnknownUser

@Megalomaniak said: You might have to include type identification for that string(the area.name == string("Pistol (pickup)") and its quite possible that the node in runtime has a different name altogether. You can check the scene tree and see it has a 'remote' option that lets you explore the scene tree of the running game when it has been launced from editor.

Sadly this didnt work. Also, i know the area.name is "Pistol (pickup)" because that's what the console prints when i stand on it. (Or is this thinking wrong?)

Maybe there's another way to do what im trying to achieve? Basically i want to be able to do different stuff depending on which area enters the character's area.

Megalomaniak

I was implying that if you have multiple of the Pistol in the scene the other ones might not be named the exact same. If instancing using unique names on them, anyways.

Hmm, maybe the issue is that you are using Input.is_action_just_pressed? It means that the name check and the start of the action/button press have to correspond perfectly timing wise.

TwistedTwigleg

@Megalomaniak said: Hmm, maybe the issue is that you are using Input.is_action_just_pressed? It means that the name check and the start of the action/button press have to correspond perfectly timing wise.

Yeah, that is probably the issue. For the code to work, you would have to press the input exactly on the same physics frame that the input is pressed, which is incredibly hard.

@Tato64 - Maybe try something like this:

var in_pickup_area = false
var sprite_texture
var pickup_area

func _on_Area2D_area_entered(area):
	print(area.name)
	if area.name == "Pistol (pickup)":
		in_pickup_area = true
		sprite_texture = con_pistola
		var pickup_area = area

# You'll need to connect this signal!
func _on_Area2D_area_exited(area):
	if in_pickup_area:
		if area == pickup_area:
			in_pickup_area = false
			pickup_area = null

func _process(_delta):
	if Input.is_action_just_pressed("rclick"):
		if in_pickup_area and pickup_area != null:
			$Sprite.set_texture(sprite_texture)
			
			pickup_area.queue_free()
			in_pickup_area = false
			pickup_area = null

UnknownUser

@Megalomaniak @TwistedTwigleg The issue with timing was correct, i set up an autoclicker spamming right click and ran over the pickup a couple of times and it triggered.

@TwistedTwigleg said: @Tato64 - Maybe try something like this:

[...]

This looks beautiful (I also learned a bit just from reading it), im confident i applied it correctly but still, didnt work.

Btw, maybe this helps: I added a print("left range") at the end of the "Area exited" signal and noticed it is not printing anything when i leave the pickup's area2d.

Thanks a lot, i look forward to your replies (I'll keep experimenting in the meantime)

TwistedTwigleg

Did you connect the signal to the _on_Area2D_area_exited function? You can do this through the Godot editor, or through code like the bit below:

func _ready():
	get_node("PathToPickupAreaHere!").connect("area_exited", this, "_on_Area2D_area_exited")

UnknownUser

@TwistedTwigleg Yup, both "area entered" and "area exited" are properly connected.

I feel like im going mad ?

If it helps in any way, this is my player:

Player #This is a KinematicBody2D
	Area2D
		CollisionShape2D
	Sprite
	CollisionShape2D

And my pickup looks like this:

Pistol (pickup) #This is just a node2D
	RigidBody2D
		CollisionPolygon2D
		Sprite
		Pistol (pickup) #This is an Area2D
			CollisionShape2D

TwistedTwigleg

Hmm, I don’t know right off. Are the areas on the same layers with the same masks?

UnknownUser

@TwistedTwigleg said: Hmm, I don’t know right off. Are the areas on the same layers with the same masks?

Sorry for the late reply, areas are both same layer same mask.

I've been stuck on this for so long I uploaded the game folder here (it's just below 2MB uncompressed) if anyone wants to take a look. (Use "sandbox.tscn" to test things, "Player" and "Pistol (pickup)" are the nodes in question.)

https://mega.nz/file/PfRGhSyD#Cycg0wAXvcysxn7L5_d9NXYrgcBIhTM4hfcPyLnYICM

cybereality

Okay, I fixed it for you.

func _on_Area2D_area_entered(area):
	if area.name == "Pistol (pickup)":
		in_pickup_area = true
		sprite_texture = pistol
		pickup_area = area

func _on_Area2D_area_exited(area):
	if in_pickup_area:
		if area == pickup_area:
			in_pickup_area = false
			pickup_area = null
			print("left range")

func _process(delta):
	if Input.is_action_just_pressed("rclick"):
		if in_pickup_area and pickup_area != null:
			$Sprite.set_texture(sprite_texture)
			var world = get_node("/root/World")
			var pistol = world.get_node("Pistol (pickup)")
			pistol.queue_free()
			in_pickup_area = false
			pickup_area = null

There were a couple bugs. First, you used "var pickup_area = area" inside one of the functions, which would declare another local variable with the same name, but not update the real global variable. Also, the queue free needed to be one the node itself, not the area. I think I might have changed one other thing, but it's all working now. Cheers.

UnknownUser

@cybereality said: Okay, I fixed it for you.
func _on_Area2D_area_entered(area):
	if area.name == "Pistol (pickup)":
		in_pickup_area = true
		sprite_texture = pistol
		pickup_area = area

func _on_Area2D_area_exited(area):
	if in_pickup_area:
		if area == pickup_area:
			in_pickup_area = false
			pickup_area = null
			print("left range")

func _process(delta):
	if Input.is_action_just_pressed("rclick"):
		if in_pickup_area and pickup_area != null:
			$Sprite.set_texture(sprite_texture)
			var world = get_node("/root/World")
			var pistol = world.get_node("Pistol (pickup)")
			pistol.queue_free()
			in_pickup_area = false
			pickup_area = null
There were a couple bugs. First, you used "var pickup_area = area" inside one of the functions, which would declare another local variable with the same name, but not update the real global variable. Also, the queue free needed to be one the node itself, not the area. I think I might have changed one other thing, but it's all working now. Cheers.

OH MY GOD, THANKS YOU SO MUCH.

Seriously, i went mad, thank you so much.