Does Godot have an equivalent to Clickteam Fusion's Perspective shader?

ringmaster

I want to make a FNAF fangame, and am using Godot because I'm broke and can't afford paid game engines. I want to go for the authentic FNAF look, so I want to know if Godot has an equivalent to Fusion's Perspective effect.

Megalomaniak

If it's some kind of screenspace effect then more than likely yes. But I have no clue what this specific perspective effect is.

Btw you might want to approve your email account so all the messages wouldn't get stuck in the moderation queue. Make sure to also check your spam filter if you can't find the email.

CoolDude07

@Megalomaniak said: If it's some kind of screenspace effect then more than likely yes. But I have no clue what this specific perspective effect is.

Btw you might want to approve your email account so all the messages wouldn't get stuck in the moderation queue. Make sure to also check your spam filter if you can't find the email.

He reffers to the Panorama shader.

cybereality

You should be able to just increase the FOV on the default Camera in Godot. I tried it and it looks pretty close to the effect you are talking about (but not exactly). You can also try Frustum projection (an option on the Camera). Otherwise you would need a custom shader (with an adjusted perspective matrix) but this might be overkill.

cybereality

Actually, I just looked into this more. These are post-processing distortion shaders, which Godot supports just fine. I actually found the original source code for the shaders on this page and they are fairly simple. https://gamejolt.com/p/perspective-shaders-for-clickteam-89in853p

Here is the panorama shader ported to Godot (I will work on the perspective one in a minute):

shader_type canvas_item;

uniform int zoom;
uniform int pDir;
uniform int noWrap;

void fragment() {
	float fB;
	float fC;
	
	float fPixelWidth = SCREEN_PIXEL_SIZE.x;
	float fPixelHeight = SCREEN_PIXEL_SIZE.y;
	
	vec2 posTex;
	vec4 color = vec4(0.0, 0.0, 0.0, 1.0);
	
	if (pDir == 0) {
		fB = 1.0 - (float(zoom) * fPixelHeight);
		fC = max(0.02, 1.0 + (fB - 1.0) * 4.0 * pow((UV.x - 0.5), 2.0));
		
		posTex = UV * vec2(1.0, fC) + vec2(0.0, (1.0 - fC) / 2.0);
		
		if (noWrap == 0 || (posTex.y >= 0.0 && posTex.y <= 1.0)) {
			color = texture(TEXTURE, posTex);
		}
	} else {
		fB = 1.0 - (float(zoom) * fPixelWidth);
		fC = max(0.05, 1.0 + (fB - 1.0) * 4.0 * pow((UV.y - 0.5), 2.0));
		
		posTex = UV * vec2(fC, 1.0) + vec2((1.0 - fC) / 2.0, 0.0);
		
		if (noWrap == 0 || (posTex.x >= 0.0 && posTex.x <= 1.0)) {
			color = texture(TEXTURE, posTex);
		}
	}
	
	COLOR = color;
}

You can read this tutorial to see how to apply full-screen shaders to viewports in Godot. https://docs.godotengine.org/en/stable/tutorials/viewports/custom_postprocessing.html

cybereality

Here is the perspective shader:

shader_type canvas_item;

uniform int zoom;
uniform int pDir;
uniform int orientation;
uniform int noWrap;

void fragment() {
	float fB;
	
	float fPixelWidth = SCREEN_PIXEL_SIZE.x;
	float fPixelHeight = SCREEN_PIXEL_SIZE.y;
	
	vec2 posTex;
	vec4 color = vec4(0.0, 0.0, 0.0, 1.0);
	
	if (pDir != 0) {
		fB = 1.0 - (float(zoom) * fPixelHeight);
		float y;
		
		if (orientation == 0) {
			y = UV.y;
		} else {
			y = 1.0 - UV.y;
		}
		
		float ScreenX = (1.0 - (1.0 - fB) * y);
		posTex = UV * vec2(ScreenX, 1.0) + vec2((1.0 - ScreenX) / 2.0, 0.0);
		
		if (noWrap == 0 || (posTex.x >= 0.0 && posTex.x <= 1.0)) {
			color = texture(TEXTURE, posTex);
		}
	} else {
		fB = 1.0 - (float(zoom) * fPixelWidth);
		float x;
		
		if(orientation == 0){
			x = UV.x;
		} else {
			x = 1.0 - UV.x;
		}
		
		float ScreenY = (1.0 - (1.0 - fB) * x);
		posTex = UV * vec2(1.0, ScreenY) + vec2(0.0, (1.0 - ScreenY) / 2.0);
		
		if (noWrap == 0 || (posTex.y >= 0.0 && posTex.y <= 1.0)) {
			color = texture(TEXTURE, posTex);
		}
	}
	COLOR = color;
}

cybereality

LOL. Just realized the OP is from 2020. Anyway, the code is here in case anyone finds it.