Enemy field of vision help.

Krisalis

I'm making a stealth game about robots that track you. When the player enters the field of vision, the robots starts going after you (unimplemented yet) , but the robot don't track the player fully as you can see in the image.

I'm not a experienced programmer and pieced this code together from tutorials and documentation from the internet, so I'm kinda lost for what would be the problem. It could probably have to do with the dot product or not.

Variables:

var player_in_range = false
var awareness = 0
var enemy_rot = Vector3 (0,0,0)
var theres_player = false

onready var enemy = get_node(".")
onready var player = enemy
onready var raycast = $RayCast

Code in Question:

func detect_player(facing_dir, enemy_pos):
	if theres_player:
		var player_pos = player.transform.origin
		var dir_to_player = enemy_pos.direction_to(player_pos)

		if dir_to_player.dot(facing_dir) > .5 and player_in_range:
			if awareness < 1 :
				awareness += player.detectability
				$AnimatedSprite3D.modulate = Color(1,1,1).blend(Color(1,0,0,awareness))
		else :
			if awareness > 0 :
				awareness -= 0.1
				$AnimatedSprite3D.modulate = Color(1,1,1).blend(Color(1,0,0,awareness))

		if awareness >= 1 :
			enemy_rot = facing_dir.cross(dir_to_player)

func enemy_movement():
	enemy.set_rotation(enemy_rot)

for a reason I don't know of, the enemy don't keep looking at the player when reaching a certain angle.

Before getting in the field of vision. Player detected. When at this point, the robot stops looking at the player.

SIsilicon28

It looks like your post got stuck in moderation queue. Make sure that you have verified your email.

cybereality

The code looks okay, but I think you might need to normalize dir_to_player and facing_dir.

Krisalis

The code looks okay, but I think you might need to normalize dir_to_player and facing_dir.

Before or after getting the cross product?

		if awareness >= 1 :
			facing_dir = facing_dir.normalized()
			dir_to_player = dir_to_player.normalized()
			enemy_rot = facing_dir.cross(dir_to_player)

func enemy_movement():
	enemy.set_rotation(enemy_rot)

I normalized it before getting the cross product but it didn't work, same problem as before.

cybereality

I meant before this line, but I'm actually not certain that's the problem.

if dir_to_player.dot(facing_dir) > .5 and player_in_range:

cybereality

Now that I'm looking at that last line, I don't think that is correct. Cross will return a vector that is perpendicular to the two inputs. So in your case it will probably made a vector either facing straight down or straight up. You can probably remove the cross product and just look_at.

func enemy_movement():
    enemy.look_at(player, Vector3(0, 1, 0))

Krisalis

I did what you told me, but still not solved.

func detect_player(facing_dir, enemy_pos):

if theres_player:
	var player_pos = player.transform.origin
	var dir_to_player = enemy_pos.direction_to(player_pos)
	facing_dir = facing_dir.normalized()
	dir_to_player = dir_to_player.normalized()

	if dir_to_player.dot(facing_dir) > .5 and player_in_range:
		if awareness < 1 :
			awareness += player.detectability
			$AnimatedSprite3D.modulate = Color(1,1,1).blend(Color(1,0,0,awareness))
	else :
		if awareness > 0 :
			awareness -= 0.1
			$AnimatedSprite3D.modulate = Color(1,1,1).blend(Color(1,0,0,awareness))

func enemy_movement():
	if awareness >= 1 :
		enemy.look_at(player.transform.origin, NORMAL)

Perhaps the problem is how the field of view is implemented, I use the dot product of dir_to_player, that is a vector pointing from the enemy to the player, with facing_dir, that is a raycast pointing forwards.

I did this because I couldn't create a collision shape that would fill the spotlight used to signify the enemy vision. (don't know what happened with CollisionPolygon but the vertexes went all over the place, thats why I couldn't use it.)

Krisalis

I managed so fix it, now the enemy faces the player in a circle. I needed to set the Raycast to the dir_to_player after awareness hits 1. This is the entire code if someone wants to use it:

extends KinematicBody

const NORMAL = Vector3(0,-1,0)

var player_in_range = false
var awareness = 0
var enemy_rot = Vector3 (0,0,0)
var theres_player = false
var direction = Vector3 (0,0,0)

onready var enemy = get_node(".")
onready var player = enemy
onready var raycast = $RayCast

func _ready():
	if enemy.owner:
		if enemy.owner.has_node("Player"):
			player = get_node("../Player")
			theres_player = true
		else :
			theres_player = false
	else :
		theres_player = false

func _process(_delta):

	var enemy_pos = enemy.transform.origin
	var facing_dir = raycast.get_cast_to()

	detect_player(facing_dir, enemy_pos)

func _physics_process(_delta):
	enemy_movement()

func detect_player(facing_dir, enemy_pos):

	if theres_player:
		var player_pos = player.transform.origin
		var dir_to_player = enemy_pos.direction_to(player_pos)
		facing_dir = facing_dir.normalized()
		dir_to_player = dir_to_player.normalized()
		direction = dir_to_player

		if dir_to_player.dot(facing_dir) > .5 and player_in_range:
			if awareness < 1 :
				awareness += player.detectability
				$AnimatedSprite3D.modulate = Color(1,1,1).blend(Color(1,0,0,awareness))
		else :
			if awareness > 0 :
				awareness -= 0.1
				$AnimatedSprite3D.modulate = Color(1,1,1).blend(Color(1,0,0,awareness))

func enemy_movement():
	if awareness >= 1 :
		enemy.look_at(player.transform.origin, NORMAL)
		raycast.set_cast_to(direction)

func _on_Range_body_entered(body):
	if body.is_in_group("Detectable") :
		player_in_range = true

func _on_Range_body_exited(body):
	if body.is_in_group("Detectable") :
		player_in_range = false

cybereality

Cool. Thanks for following up with the solution.