FPS character Controller link to touch joystick

rafatparvez

need help to connect joystick to player i am beginner i want to understand joystick is returning vector2 value and player has vector3 control how to connect them here is script

extends KinematicBody # player

var camera_angle = 0
var mouse_sensitivity = 0.3
var velocity = Vector3()
var direction = Vector3()

var gravity = -9.8 * 3
const max_speed = 20
const Accel = 2
const Daccel = 6

onready var joystick = get_parent().get_node("Control/Joystick/TouchScreenButton")

func _ready():
	pass # Replace with function body.

func _physics_process(delta):
	# reset player direction
	direction = Vector3()
	# get rotation of camera
	var aim = $Head/Camera.global_transform.basis
	
	if Input.is_action_pressed("move_forward"):
		direction -= aim.z
	if Input.is_action_pressed("move_backward"):
		direction += aim.z
	if Input.is_action_pressed("move_left"):
		direction -= aim.x
	if Input.is_action_pressed("move_right"):
		direction += aim.x
	
	direction = direction.normalized()
	
	
	velocity.y += gravity * delta
	var temp_velocity = velocity
	temp_velocity.y = 0
	
	var speed = max_speed	
	
	var target = direction * speed
	
	var accelaration
	if direction.dot(temp_velocity) > 0:
		accelaration = Accel
	else:
		accelaration = Daccel
	
	temp_velocity = temp_velocity.linear_interpolate(target, accelaration * delta)
	velocity.x = temp_velocity.x
	velocity.z = temp_velocity.z
	
	velocity = move_and_slide(velocity, Vector3(0,1,0))

func _input(event):
	if event is InputEventMouseMotion:
		$Head.rotate_y(deg2rad(-event.relative.x * mouse_sensitivity))
		
		var change = -event.relative.y * mouse_sensitivity
		if change + camera_angle < 90 and change + camera_angle > -90:
			$Head/Camera.rotate_x(deg2rad(change))
			camera_angle += change

extends TouchScreenButton #joystick

var radius = Vector2(77, 77)
var boundary = 124

var ongoing_drag = -1

var return_accel = 20

var threshold = 10

func _process(delta):
	if ongoing_drag == -1:
		var pos_difference = (Vector2(0, 0) - radius) - position
		position += pos_difference * return_accel * delta

func get_button_pos():
	return position + radius

func _input(event):
	if event is InputEventScreenDrag or (event is InputEventScreenTouch and event.is_pressed()):
		var event_dist_from_centre = (event.position - get_parent().global_position).length()

		if event_dist_from_centre <= boundary * global_scale.x or event.get_index() == ongoing_drag:
			set_global_position(event.position - radius * global_scale)

			if get_button_pos().length() > boundary:
				set_position( get_button_pos().normalized() * boundary - radius)

			ongoing_drag = event.get_index()

	if event is InputEventScreenTouch and !event.is_pressed() and event.get_index() == ongoing_drag:
		ongoing_drag = -1

func get_value():
	if get_button_pos().length() > threshold:
		return get_button_pos().normalized()
	return Vector2(0, 0)

TwistedTwigleg

Welcome to the forums @rafatparvez!

To make a joystick work in a FPS, you will need to use the Vector2 returned by the joystick like the Vector2 recieved from the mouse position. However, because the touchscreen joystick is not an input event, and does not provide signals, you will need to process joystick input either in _process or _physics_process.

From a code point of view, it is more or less exactly what you are already doing, you just need to use the value returned by the get_value function from the joystick in the code.

For example, adding the following to _process should make the joystick rotate the camera:

var joystick_vector = joystick.get_value()
if joystick_vector != Vector2.ZERO:
	# You’ll probably need to make a new sensitivity variable for the
	# joystick. For this example, I’m just using mouse_sensitivity.
	$Head.rotate_y(deg2rad(-joystick_vector.x * mouse_sensitivity))
	var change = -joystick_vector.y * mouse_sensitivity
	if change + camera_angle < 90 and change + camera_angle > -90:
		$Head/Camera.rotate_x(deg2rad(change))
		camera_angle += change

rafatparvez

@TwistedTwigleg thanks for quick reply

Also I want control player movement by joystick since i am exporting this demo for android

i am 2d/3d (prop designer) artist working as freelancer I am totally beginner in coding

since Godot is awesome opensource project with great community I want to learn and recommend to my clients

here is some model import in Godot https://www.reddit.com/r/godot/comments/fxx5a4/godot_is_game_changer_one_of_the_best_open_source/?utm_source=share&utm_medium=web2x

https://www.reddit.com/r/godot/comments/fzcafo/fps_proto/?utm_source=share&utm_medium=web2x

https://www.reddit.com/r/godot/comments/fuwmrf/godot_automotive_lighting_study/?utm_source=share&utm_medium=web2x

TwistedTwigleg

No problem! For movement, you just need to add the following after line 32 of the player script (untested):

var joystick_vector = joystick.get_value()

# Note: We do not need to do any condition checking for the joystick, because
# get_value returns an empty Vector2 when the joystick is not being used
# and adding an empty Vector2 will not do anything adverse to the direction
# variable.

# For movement forward and backwards, we want to use the Y value of
# the joystick. This is because up/down on the joystick will map to
# the Y axis, since the joystick is in 2D.
direction += joystick_vector.y
# For movement right/left, we can just use the X value of the joystick.
direction += joystick_vector.x

rafatparvez

i am getting this error

if I want to learn from scratch what should I learn first?

Megalomaniak

change it to

  direction.y += joystick_vector.y
  direction.x += joystick_vector.x

rafatparvez

@Megalomaniak Thank you so much, It works One step Closer :3

TwistedTwigleg

@Megalomaniak is right, you have to adjust the individual axis values to those of the joystick for the code I posted.

Though, after looking at the code again, I think it might need to be the following instead:

direction += aim.z.normalized() * joystick_vector.y
direction += aim.x.normalized() * joystick_vector.x

So it takes the camera’s view into account.

As for learning, I’d recommend going through the Godot documentation if you have not already. I would also recommend going through some Godot YouTube tutorials, like those from GDQuest and HeartBeast.

rafatparvez

@TwistedTwigleg @Megalomaniak Thank for all your help It is working fine with above code sure i will go through all YouTube channels