Loopin Area2D.

Johyn

Greets!

Here's the blocking: i'd like to start again the random position of my Area2Ds after their previous position, in some kind of loop and end it with a change scene.

This is the code so far:

extends Node2D

func _ready():
   
   var screenSize = get_viewport().get_visible_rect().size
   var rng = RandomNumberGenerator.new()
   rng.randomize()
   var rndX = rng.randi_range(0, screenSize.x)
   var rndY = rng.randi_range(0, screenSize.y)
   var rndX2 = rng.randi_range(0, screenSize.x)
   var rndY2 = rng.randi_range(0, screenSize.y)
   var rndX3 = rng.randi_range(0, screenSize.x)
   var rndY3 = rng.randi_range(0, screenSize.y)
   var rndX4 = rng.randi_range(0, screenSize.x)
   var rndY4 = rng.randi_range(0, screenSize.y)
   var rndX5 = rng.randi_range(0, screenSize.x)
   var rndY5 = rng.randi_range(0, screenSize.y)
   
   $Area2D.position = Vector2(rndX, rndY)
   $Area2D2.position = Vector2(rndX2, rndY2)
   $Area2D3.position = Vector2(rndX3, rndY3)
   $Area2D4.position = Vector2(rndX4, rndY4)
   $Area2D5.position = Vector2(rndX5, rndY5)

func _on_Timer_timeout():
   
   var rng = RandomNumberGenerator.new()
   var nextToggleSeconds = rng.randi_range(5, 15) # toggle in 5 to 15 seconds
   
   $Area2D.visible = !$Area2D.visible # switch visibility
   $Area2D2.visible = !$Area2D2.visible
   $Area2D3.visible = !$Area2D3.visible
   $Area2D4.visible = !$Area2D4.visible
   $Area2D5.visible = !$Area2D5.visible
   $Timer.start(nextToggleSeconds)

What should be added please?

cybereality

Looks like that should work, put you can simplify it greatly with functions and loops with groups.

For example this code (make sure to add all your Area2Ds to the "area" group in the editor):

extends Node2D

func _ready():
   randomize()
   var screen_size = get_viewport().get_visible_rect().size
   for area in get_tree().get_nodes_in_group("areas"):
       area.position = get_rand_position(screen_size)

func get_rand_position(var size):
    var rand_x = rand_range(0, size.x)
    var rand_y = rand_range(0, size.y)
    return Vector2(rand_x, rand_y)

func _on_Timer_timeout():
   var next_seconds = rand_range(5, 15) 
   for area in get_tree().get_nodes_in_group("areas"):
       area.visible = !area.visible
   $Timer.start(next_seconds)

Johyn

Thxs, but i don't know how to use the 'group'... :s Should i just put all my 'areas2D' under a single node?

cybereality

Click on the object, then look on the right side there is a tab called node. Click it and then type in "areas" (or whatever group you want to call it) and click add. You'll have to do this for each object if they are loose. Better to make them into a scene, that way you only have to do that once.

Johyn

Ok, made the group, but got an error on line 10: Method 'randi_range' is not declared in the current class...

cybereality

Sorry, that was my mistake. It's called "rand_range".

Usually I test the code I post, but I just did this one in my head. Thanks for understanding.

Johyn

No prob at all. :)

Result is a bit like the previous code: Area2Ds that apears on random position, and stay there, though they do flicker from timer. The strange is that one is always apearin, others less frequently and one only once in about 50 tests...

cybereality

Here is some updated code to test. I tried it and it seems to work (make sure the groups are setup right):

extends Node2D

onready var screen_size = get_viewport().get_visible_rect().size
onready var areas = get_tree().get_nodes_in_group("areas")
onready var timer = get_node("Timer")

func _ready():
	randomize()
	randomize_areas()
	timer.connect("timeout", self, "on_timeout")
	timer.start(2)

func randomize_areas():
	for area in areas:
		area.position = get_rand_position(screen_size)
	
func get_rand_position(var size):
	var rand_x = rand_range(0, size.x)
	var rand_y = rand_range(0, size.y)
	return Vector2(rand_x, rand_y)
	
func on_timeout():
	var next_seconds = rand_range(1, 3)
	for area in areas:
		area.visible = !area.visible
	randomize_areas()
	timer.start(next_seconds)

Johyn

That works great! :D But for that lil error: Error calling method from signal 'timeout': 'Node2D(CCreation.gd)::on_Timer_timeout': Method not found._

cybereality

That was because I connected the timer in code. If you use my way, you'll have to remove the signal callback you created in the editor.

Johyn

Here. Clean as a new scene. Cheeers! :D

Johyn

Greets! What if i want to add another Area2D, but not in the group, with a specifix timer?